テストするスマートコントラクトを書く

前回はHardhatの環境構築を行いました。

今回はテスト対象のスマートコントラクトを書いていきます。

スマートコントラクトのディレクトリを作成する
スマートコントラクトを作成する
コントラクトで使うパッケージをインストールする
コントラクトをコンパイルする
次のセクションへ

スマートコントラクトのディレクトリを作成する

まずはスマートコントラクト用のディレクトリを作成しましょう。

VSCodeやターミナルからcontractsディレクトリを作ってください。

.
├── contracts  // ★ここを追加
├── hardhat.config.js
├── node_modules
├── package-lock.json
└── package.json

スマートコントラクトを作成する

NFTをmintするスマートコントラクトを作っていきます。

contractsディレクトリの配下に、NFT.solファイルを作って、下記のコードをコピペしてください。

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.9;

import "@openzeppelin/contracts/access/Ownable.sol";
import "@openzeppelin/contracts/utils/Strings.sol";
import "@openzeppelin/contracts/token/ERC721/extensions/ERC721Enumerable.sol";

contract NFT is ERC721Enumerable, Ownable {
  using Strings for uint256;

  string baseURI;
  string public baseExtension = ".json";
  uint256 public cost = 0.0005 ether;
  uint256 public maxSupply = 30;
  uint256 public maxMintAmount = 3;
  bool public paused = false;
  bool public revealed = false;
  string public notRevealedUri;

  constructor(
    string memory _name,
    string memory _symbol,
    string memory _initBaseURI,
    string memory _initNotRevealedUri
  ) ERC721(_name, _symbol) {
    setBaseURI(_initBaseURI);
    setNotRevealedURI(_initNotRevealedUri);
  }

  // internal
  function _baseURI() internal view virtual override returns (string memory) {
    return baseURI;
  }

  // public
  function mint(uint256 _mintAmount) public payable {
    uint256 supply = totalSupply();
    require(!paused);
    require(_mintAmount > 0);
    require(_mintAmount <= maxMintAmount);
    require(supply + _mintAmount <= maxSupply);

    if (msg.sender != owner()) {
      require(msg.value >= cost * _mintAmount, "eth is not enough!!");
    }

    for (uint256 i = 1; i <= _mintAmount; i++) {
      _safeMint(msg.sender, supply + i);
    }
  }

  function walletOfOwner(address _owner)
    public
    view
    returns (uint256[] memory)
  {
    uint256 ownerTokenCount = balanceOf(_owner);
    uint256[] memory tokenIds = new uint256[](ownerTokenCount);
    for (uint256 i; i < ownerTokenCount; i++) {
      tokenIds[i] = tokenOfOwnerByIndex(_owner, i);
    }
    return tokenIds;
  }

  function tokenURI(uint256 tokenId)
    public
    view
    virtual
    override
    returns (string memory)
  {
    require(
      _exists(tokenId),
      "ERC721Metadata: URI query for nonexistent token"
    );
    
    if(revealed == false) {
        return notRevealedUri;
    }

    string memory currentBaseURI = _baseURI();
    return bytes(currentBaseURI).length > 0
        ? string(abi.encodePacked(currentBaseURI, tokenId.toString(), baseExtension))
        : "";
  }

  //only owner
  function reveal() public onlyOwner {
      revealed = true;
  }
  
  function setCost(uint256 _newCost) public onlyOwner {
    cost = _newCost;
  }

  function setmaxMintAmount(uint256 _newmaxMintAmount) public onlyOwner {
    maxMintAmount = _newmaxMintAmount;
  }

  function setMaxSupply(uint256 _maxSupply) public onlyOwner {
    maxSupply = _maxSupply;
  }
  
  function setNotRevealedURI(string memory _notRevealedURI) public onlyOwner {
    notRevealedUri = _notRevealedURI;
  }

  function setBaseURI(string memory _newBaseURI) public onlyOwner {
    baseURI = _newBaseURI;
  }

  function setBaseExtension(string memory _newBaseExtension) public onlyOwner {
    baseExtension = _newBaseExtension;
  }

  function pause(bool _state) public onlyOwner {
    paused = _state;
  }
 
  function withdraw() public payable onlyOwner {    
    // This will payout the owner 95% of the contract balance.
    // Do not remove this otherwise you will not be able to withdraw the funds.
    // =============================================================================
    (bool os, ) = payable(owner()).call{value: address(this).balance}("");
    require(os);
    // =============================================================================
  }
}

コントラクトで使うパッケージをインストールする

このNFTのコントラクトは、openzeppelinのパッケージを使用しています。

ターミナルを開いて、下記のコマンドでパッケージをインストールしてください。

npm install @openzeppelin/contracts

コントラクトをコンパイルする

最後に、作ったコントラクトがコンパイルできるか確認します。

ターミナルで下記コマンドを入力してください。

npx hardhat compile

下記のように出力されればコンパイル成功です。

Compiled xx Solidity files successfully

次のセクションへ

これでテスト対象のスマートコントラクトができました。

誰でもできる！ジェネラティブNFT開発ではこれをテストネットにデプロイして挙動を確認していました。

次の講座からは

テストネットを使わず
Hardhatのローカルネットワークで
自動で何度もテストする

ためのテストコードを書いていきます。